3.2 Les chaînes de charactères

Dans le langage Scilab, elles sont délimitées par des apostrophes ou des guillemets (anglais), et lorsqu'une chaîne contient un tel caractère, il faut le doubler. Ainsi pour faire afficher:Scilab c'est "cool" On utilisera:

 
-->"Scilab c''est ""cool"""
 ans  =
 
 Scilab c'est "cool"

ou encore:

  
 -->'Scilab c''est ""cool""'   
 ans  =
 
 Scilab c'est "cool"

On peut aussi définir des matrices de chaînes de caractères:

-->Ms=["a" "bc" "def"]
 Ms  =
 
!a  bc  def  !
 
-->size(Ms)
 ans  =
 
!   1.    3. !
 
-->length(Ms)
 ans  =
 
!   1.    2.    3. !

Noter que length n'a pas le même comportement que sur une matrice de nombres: pour une matrice de chaînes de caractères M, length(M) renvoie une matrice d'entiers de même format que M où le coefficient en position(i,j) donne le nombre de caractères de la chaîne en position (i,j).

La concaténation de chaînes de caractères utilise simplement +:

-->s1='abc'; s2='def'; s=s1+s2
 s  =
 
 abcdef

et l'extraction se fait via la fonction part:

-->part(s,3)
 ans  =
 
 c   
 
-->part(s,3:4)
 ans  =
 
 cd

Le deuxième argument de la fonction part est donc un vecteur d'indices (ou un simple scalaire entier) désignant les numéros de caractères que l'on veut extraire. La création d'une matrice de chaînes de caractères s'effectue simplement, la matrice se rentre de la même manière qu'avec des entiers,en rajoutant des guillemets.

 
-->C=['a' 'c';'d' 'e']
 C  =
 
!a  c  !
!      !
!d  e  !

Pour donner des valeurs aux différents coefficients de la matrice, il faut utiliser la fonction evstr de la manière suivante:

-->a=1;c=3;d=1;e=4; \\on affecte aux différentes variables des valeurs
 
-->evstr(C)
 ans  =
 
!   1.    3. !
!   1.    4. !