4.3.2 Synthaxe générale

La synthaxe générale de plot2d est la suivante:

plot2di(Mx,My,[style,strf,leg,rect,nax])

L'index i de plot2d peut prendre 5 valeurs:

• i est omis : tracé linéaire
• i=1 : comme précédemment avec possibilités d'échelleslogarithmiques
• i=2 : tracé "en escalier"
• i=3 : tracé de barres verticales
• i=4 : tracé de flèches

Illustrons ces différents plot2d par un exemple complet, qui fait également appel à la fonction xsetech décrite précédemment.

-->t=(1:0.1:8)';xset("font",2,3);  
        
-->xsetech([0.,0.,0.5,0.5],[-1,1,-1,1]);  
 
-->plot2d([t,t],[1.5+0.2*sin(t) 2+cos(t)]); 

-->xtitle('Plot2d');                           
 
-->titlepage('Trace lineaire');
 
-->xsetech([0.5,0.,0.5,0.5],[-1,1,-1,1]);  
 
-->plot2d1('oll',t,[1.5+0.2*sin(t) 2+cos(t)]);
 
-->xtitle('Plot2d1');
 
-->titlepage('Echelles logarithmiques')
 
-->xsetech([0.,0.5,0.5,0.5],[-1,1,-1,1]);   
  
-->plot2d2('onn',t,[1.5+0.2*sin(t) 2+cos(t)]);
 
-->xtitle('Plot2d2'); 

 -->titlepage('Trace en escalier')  
 
-->xsetech([0.5,0.5,0.5,0.5],[-1,1,-1,1]);    
 
-->plot2d3('onn',t,[1.5+0.2*sin(t) 2+cos(t)]);
 
-->xtitle('Plot2d3');                         
 
-->titlepage('Barres verticales')

On obtient ainsi le graphe suivant:

Figure: Différents plot2d

Les arguments entre crochets de plot2d sont des arguments optionnels. Ils ont la signification suivante:

• style est un vecteur ligne de dimension nc, sa $i^{\grave{e}me}$ composante spécifiant le style de la $i^{\grave{e}me}$ courbe. Sur un terminal couleur, si style(i) est un entier strictement positif k, la courbe correspondante sera dessinée avec la couleur numéro k (on peut voir quelques numéros de couleur sur un tableau à la fin de ce paragraphe, mais xset() vous les montrera toutes), alors que sur un terminal noir et blanc, on aura des traits avec différents pointillés. Par contre, si style(i) est un entier négatif ou nul, chaque point de la courbe est repéré par un petit symbole (point, triangle, rond, croix, plus, etc...) et les points ne sont alors pas reliés.

  
  

• strf est une chaîne de trois caractères "xyz" telle que:

  
  

  • si x est le caractère 1, alors une légende pour chacune des courbes (donnée par leg qui doit alors être présent dans la liste des arguments) sera affichée. Pour les autres valeurs de x, la légende n'est pas affichée.

    
    

  • le caractère y spécifie le calcul de l'échelle, c'est-à-dire le rectangle
    $x_{min},y_{min},x_{max},y_{max}$ qui va déterminer la frontière du graphe:
    • pour y=0, on utilise l'échelle précédente (celle qui a été déterminée par un appel précédent)

    • pour y=1, l'échelle est donnée par l'argument rect

    • pour y=2, Scilab calcule automatiquement l'échelle (en prenant les max et les min de Mx et My

    • pour les autres possibilités, voir le Help

  • le caractère z permet de régler le pourtour du graphe:

    
    

    • pour z=1, le graphe est entouré d'une boîte (dont les dimensions sont $x_{min},y_{min},x_{max},y_{max}$ et les côtés ouest (l'axe des y) et sud (l'axe des x) sont gradués (la graduation est automatique ou est spécifiée par le paramètre nax)

    • pour z=2, le graphe est simplement entouré de la boîte
      $x_{min},y_{min},x_{max},y_{max}$

    • pour les autres valeurs, il n'y a ni boîte, ni axe

• le paramètre leg est une chaîne de caractères qui donne une légende pour chacune des courbes 'y1@y2@...'. Chaque légende est séparée de la suivante par le symbole @. Si vous fournissez $n$ légendes alors qu'il y a $nc$ courbes ($n<nc$), seules les $n$ premières courbes auront une légende.

  
  

• rect=[xmin, ymin, xmax, ymax] sert à spécifier l'échelle.

  
  

• nax=[nx,Nx,ny,Ny] sert à choisir les graduations: Nx est le nombre d'intervalles en $x$ (on obtient alors Nx+1 valeurs numériques), nx le nombre de sous-intervalles par intervalle (ainsi, une valeur de nx=2 donnera une petite graduation entre deux grandes). ny et Ny ont la même signification, mais pour l'axe des y.

  
  Attention: si vous avez besoin du $i^{\grave{e}me}$ argument, il faut impérativement fournir tous les arguments précédents. Ainsi, si vous voulez choisir précisément les graduations(avec z=1 et nax), il faut alors fournir tous les paramètres précédents (avec éventuellement des valeurs "vides" si elles ne sont pas utilisées, par exemple: leg=' ', rect=[1:4]).

Tableau 4.1: Quelques couleurs de la carte

numéro	couleur
1	noir
2	bleu foncé
3	vert clair
4	cyan
5	rouge vif
6	mauve
26	marron
29	rose
32	jaune orangé

Voici un premier exemple avec presque tous les paramètres. Nous allons ainsi tracer une ellipse, un cercle et la fonction erreur. On définira par ailleurs la fenêtre, les légendes et un titre.

-->t=linspace(0,2*%pi,60)';                          

-->x1=2*cos(t);y1=sin(t);                            
 
-->x2=cos(t);y2=y1;                                  
 
-->x3=linspace(-2,2,60)';y3=erf(x3);                 
 
-->rect=[-2.05,-1.4,2.05,1.4];                       
 
-->leg="ellipse@cercle@fct erreur";                  
 
-->plot2d([x1 x2 x3],[y1 y2 y3],[1:3],"111",leg,rect)
 
-->xtitle("De nouvelles courbes...","x","y")

Figure 4.5: Une ellipse, un cercle et la fonction erreur

D'une manière générale, on utilisera donc l'instruction plot2d de la façon suivante (où nc est le nombre de courbes):

plot2d(Mx,My,[1:nc],"121","leg_1 @...@ leg_nc")

Ceci permet en effet de récupérer chacune des différentes courbes par une légende, tout en calculant automatiquement l'échelle.

Par contre, imposer la fenêtre rect avec y=1 peut être utile pour améliorer la qualité de son graphique, car le dimensionnement automatique colle les courbes à la fenêtre. On peut alors la calculer avec les commandes suivantes:

-->x0=min(Mx);x1=max(Mx);

-->y0=min(My);y1=max(My);

-->dx=(x1-x0)*0.05;dy=(y1-y0)*0.05;

-->xmin=x0-dx;xmax=x1+dx;ymin=y0-dy;ymax=y1+dy;