
set(
	QTDBUSTEST_SRC
	DBusTestRunner.cpp
	DBusService.cpp
	QProcessDBusService.cpp
	SuicidalProcess.cpp
)

set(
	QTDBUSTEST_PUBLIC_HEADERS
	"${CMAKE_CURRENT_BINARY_DIR}/config.h"
	DBusTestRunner.h
	DBusService.h
	QProcessDBusService.h
	SuicidalProcess.h
)

add_library(
	qtdbustest${QT_SUFFIX}
	SHARED
	${QTDBUSTEST_SRC}
)

target_link_libraries(
	qtdbustest${QT_SUFFIX}
	Qt::Core
	Qt::DBus
	Qt::Test
)

set_target_properties(
	qtdbustest${QT_SUFFIX}
	PROPERTIES
	VERSION ${API_VERSION}.0.0
	SOVERSION ${ABI_VERSION}
	PUBLIC_HEADER "${QTDBUSTEST_PUBLIC_HEADERS}"
)

install(
	TARGETS qtdbustest${QT_SUFFIX}
	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
	PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/libqtdbustest${QT_SUFFIX}${API_SUFFIX}/libqtdbustest"
)

# Package config

set(LIBQTDBUSTEST_PC "${CMAKE_CURRENT_BINARY_DIR}/libqtdbustest${QT_SUFFIX}${API_SUFFIX}.pc")
set(LIBQTDBUSTEST_REQUIRES Qt${QT_VERSION_MAJOR}Core)
configure_file("libqtdbustest.pc.in" "${LIBQTDBUSTEST_PC}" @ONLY)

install(
	FILES "${LIBQTDBUSTEST_PC}"
	DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig"
)
